Prezentacja interaktywna

Clear[x]

Parametry dynamiczne

Z zasady wszelkie zmiany, które mogą mieć wpływ na wynik obliczeń dokonywane są w celach (komórkach) wejściowych (In[]). Pojawia się jednak potrzeba, aby w niektórych sytuacjach cela wyjściowa (Out[]) wyposażona była w parametr umożliwiający zmianę wyniku. Takie parametry określane są mianem parametrów dynamicznych. Modyfikacja wyniku droga zmiany parametru dynamicznego nie wymaga wykonania celi wejściowej, lecz dokonywana jest wprost w celi zawierającej wynik. Interpretacja tych parametrów nie odbywa się na poziomie jądra programu (kernela) ale na poziomie wyświetlania. Odpowiednio sporządzone cele interaktywne zachowują swoje dynamiczne własności przy wyswietleniu MathPlayer'em a zatem sa dostepne dla użytkowników nie posiadający licencji Mathematica.

Parametr ciągły

Suwak (Slider)

Slider[Dynamic[x]]

DynamicModule[{a},{Slider[Dynamic[a]],Dynamic[Sin[a x]]}]

Manipulate[Plot[a x Sin[a x],{x,0,6}],{a,1,5}]
(*Help*)

Clear[a,x]
Manipulate[Solve[a (x^2)+ x +1==0,x], {a, 1,6}]

Manipulate[Style[N[Pi,n],Small],{n,10^2,10^4,10^2}]
(*Help*)

Manipulate[{N[11/19,a],Precision[N[2/3,a]]},{a,1,60}]
(*Help*)

Manipulowanie grafiką (DynamicModule, Manipulate)

Manipulate[ContourPlot3D[x^2+y^2+a z^3==1,{x,-2,2},{y,-2,2},{z,-2,2},Mesh->None],{a,-2,2}]
(*Help*)

DynamicModule[{a},{Slider[Dynamic[a]],Dynamic[ContourPlot3D[(x^2)+(y^2)+a (z^3)==1,{x,-2,2},{y,-2,2},{z,-2,2},Mesh->None]]}]

Framed[Graphics3D[Cuboid[{0,0,0}],SphericalRegion->True]]
(*Help*)

Clear[x,y,z]
rysuj:=RegionPlot3D[uklad,{x,-s,s},{y,-s,s},{z,-s,s}]
uklad=Or@@{x y z>1,(x^2)+(y^2)+(z^2)<20};

s=6;rysuj

Kontrolery (ControllerInformation)

ControllerInformation[]

Parametr dyskretny

Manipulate[Plot[a x Sin[a x],{x,0,6}],{a,{1,3,5}}]

Manipulate[Plot[f[x],{x,0,2Pi}],{f,{Sin,Cos,Tan,Cot}}]

Okienko tekstowe

Manipulate[Plot[f[x],{x,0,10}],{f,Tan}]

Wybór/Menu

{Manipulate[Plot[f[x],{x,0,2Pi}],{f,{Sin,Cos,Tan,Cot}}],Manipulate[Plot[f[x],{x,0,2Pi}],{f,{Sin,Cos,Tan,Cot},ControlType->PopupMenu}]}

Zestawy parametrów dynamicznych

Suwak

Clear[r,R]

Zmienne kartezjańskie i radialne

x:=(R+r Cos[ϕ]) Cos[θ]
y:=(R+r Cos[ϕ]) Sin[θ]
z:=r Sin[ϕ]

X[r_,R_]={x,y,z}

F[r_,R_]:=ParametricPlot3D[X[r,R],{ϕ,0,2 π},{θ,0,2 π}]

Manipulate[F[r,R],{r,0,4}, {R,0,8}]

Manipulate[ParametricPlot[{a1 Sin[n1 (x+p1)],a2 Cos[n2 (x+p2)]},{x,0,20Pi},PlotRange->1,PerformanceGoal->"Quality"],Style["Vertical",Bold,Medium],{{n1,1,"Frequency"},1,4},
{{a1,1,"Amplitude"},0,1},{{p1,0,"Phase"},0,2Pi},Delimiter,
Style["Horizontal",Bold,Medium],{{n2,5/4,"Frequency"},1,4},{{a2,1,"Amplitude"},0,1},
{{p2,0,"Phase"},0,2Pi}, ControlPlacement->Left]
(*Help*)

Współrzędne

Manipulate[F[d[[1]],d[[2]]],{d,{0,0},{π,π}}]

Locator

DynamicModule[{pts={{0,0},{1,1},{2,0},{3,2}}},LocatorPane[Dynamic[pts],Dynamic[Plot[InterpolatingPolynomial[pts,x],{x,0,3},PlotRange->3]]]] (*Help*)

Manipulate[Graphics[Polygon[pt],PlotRange->2],{{pt,{{0,0},{1,0},{1,1},{0,1},{1,-1}}},Locator,LocatorAutoCreate->True}]
(*Help*)