Działania na równaniach stronami

Lewa  i prawa strona równania

Mathematica traktuje równania jak listy. Dla równania r

r=           3x+4y==f[x,y]

można lewą i prawą strone otrzymać przy użyciu funkcji Part lub funkcji First, Last. 
A wiec lewa strona:

r[[1]]
(*lub*) r//First

i prawa strona

r[[2]]
(*lub*) r//Last

Przekształcenie równania w listę i odwrotnie

r=           3x+4y==f[x,y]

Napiszemy obie strony równania w postaci listy

List@@ r

Operacja odwrotna

Equal @@ %

Dodawanie równań stronami

Clear[r]

Układ równań

uklad={3x+4y==6,x-14y==8,5x-y==-2};
%//TableForm

Buduję operator dodawania rówanań stronami

dodajstronami=Equal@@Total@Apply[List,#,1]&;

Sumuję równania stronami

dodajstronami[uklad]

Kombinacje liniowe równań

Buduję operator kombinacji liniowej

kombinuj=Simplify/@Equal@@Total[#2 Apply[List,#1,1]]&;

Dodaję równania stronami z mnożnikami {1,2,3}

kombinuj[uklad,{1,2,3}]

Inny układ

uklad={ 3 (x^2)+4 ∫f[y]\[DifferentialD]y==6,(∂_x)f[x]-14 y==8, 5 x-y==0};
%//TableForm//TraditionalForm

Dodaję równania stronami z mnożnikami {1,2,3}

kombinuj[uklad,{1,2,3}]//TraditionalForm

Różniczkowanie stronami

Różniczkowanie stronami

f[x]==Sin[x];
D[#,x]&/@ %

Różniczkowanie cząstkowe (dwukrotne względem x) stronami

Derivative[2,0][F][t,x]==((2 a'[t] )/(a[t]))(G[t,x]-Derivative[1,0][F][t,x]);
D[#,{x,2}]&/@   %//Simplify

Całkowanie stronami

f[x]==Sin[x];
Integrate[#,x]&/@ %

∫#1\[DifferentialD]x&/@   (f[x]==Sin[x])

Dowolny operator działajacy stronami

r=           3x+3y==z

Sin/@r

2((#1)^2)&/@r

Simplify/@ r

Przeniesienie ze znakiem minus

r

Subtract@@ r==0